10 REM calculated load capacitance for long wire antenna though the HF bands
20 REM inductance to wire is 300nH / metre length
30 REM 15metres of wire is half wavelenght at 10MHz, the wire has an inductance of 4.5uH equivalent coil
40 REM reason : 1 metre of wire is equal to 300nH
50
60 REM the Zo=SQR(RL^2 - XL^2) equation is the add on to the co-axial cable, the antenna end
70 REM Thus so, with XL = 50, then the above equation then equals zero, and hence does add to the
80 REM antenna with an antenna reactive loading.
90 REM
100
110 REM The value of reference in the Zo=SQR() equation is the cable impedance, as XL =50,
120 REM the added load of the antenna to the cable equates to zero offset.
130
140 REM By using the cable impedance, the wire is matched to the cable characteristic value.
150
160 REM However if a 1/4 wavelength wire inductive resonance reactance value is used as RL, RL = 141ohms,
170 REM then the wire is matched to the 1/4 wave length terminal impedance.
180
190 REM for the 1/4 wave length match to be used, the ATU would have an input PI section Low Pass Filter, Fc = 30MHz
200 REM the input of the LPF would be 50ohms to match the RF co-axial cable, but the LPF output would be 141ohms.
210
220
230 REM length_metres = the length of wire used for antenna, calculated into the equivalent inductance value
240
250 length_metres = 50
260 l = (length_metres*(300E-9))
270 length_feet = ((100/2.54)*length_metres)/12
280
290 REM the reactance_resonant_impedance is twice the cable impedance, or as required reactance_resonant_impedance for a matching stub, both used as the reference for RL
300 reactance_resonant_impedance = 50
310
320 PRINT " reactance resonant impedance = ";reactance_resonant_impedance;"ohms"
330 PRINT " inductance of wire / coil = ";l*1E6;"uH inductance of a length of equivalent wire = ";INT(length_feet);"feet or ";length_metres;"metres"
340
350
360 REM PRINT " length of equivalent wire = ";INT(length_feet);"feet or ";length_metres;"metres"
370
380 PRINT
390
400 FOR f = 0.1 TO 1 STEP 0.1
410
420 REM inductive reactance
430 XL= (2*PI*(f*1E6)*l)
440
450 REM RL is low to reactance_resonant_impedance, thus the wire is capacitive and needs inductive loading
460 IF XL <= reactance_resonant_impedance THEN PROC_low
470
480 REM RL is high to reactance_resonant_impedance, thus thwe wire is inductive and needs capacitive loading
490 IF XL > reactance_resonant_impedance THEN PROC_high
500
510 NEXT f
520
530
540 FOR f = 1 TO 30 STEP 1
550
560 REM inductive reactance
570 XL= (2*PI*(f*1E6)*l)
580
590 REM RL is low to reactance_resonant_impedance, thus the wire is capacitive and needs inductive loading
600 IF XL <= reactance_resonant_impedance THEN PROC_low
610
620 REM RL is high to reactance_resonant_impedance, thus the wire is inductive and needs capacitive loading
630 IF XL > reactance_resonant_impedance THEN PROC_high
640
650 NEXT f
660 END
670
680
690
700
710 REM RL is low to reactance_resonant_impedance, thus the wire is short and capacitive thus needs inductive loading
720 DEF PROC_low
730 Xc_low = SQR(reactance_resonant_impedance^2 - XL^2)
740 REM Xc_low used as XL, as opposite reactance required
750 XLoad = Xc_low/((2*PI*(f*1E6)))
760 PRINT TAB(1);" freq= ";f;"MHz";TAB(19);" XL=";XL;TAB(35);" Xload=";XLoad*1E6;"uH"
770 ENDPROC
780
790
800 REM RL is high to reactance_resonant_impedance, thus the wire is long and inductive thus needs capacitive loading
810 DEF PROC_high
820 XL_high = SQR(XL^2 - reactance_resonant_impedance^2)
830 REM XL used as Xc, as opposite reactance required
840 Xcload = 1/((2*PI*(f*1E6)*XL_high))
850 PRINT TAB(1);" freq= ";f;"MHz";TAB(19);" XL=";XL;TAB(35);" Cload=";Xcload*1E12;"pF"
860 ENDPROC